关于autorun.inf的问题
发布网友
发布时间：2022-05-12 07:44
我来回答
共6个回答
热心网友
时间：2024-02-19 22:03
将以下内容保存为.bat文件
@Echo Off
color 2f
title Autorun 病毒清除工具——有脑分析
Rem 杀进程
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
:clearauto
cls
Echo.
Echo Autorun 病毒清除工具
Echo.
Echo.
Echo.
Echo 制作：有脑分析
Echo.
Echo 本程序运行后自动清除每个盘符下的Autorun病毒
Echo 本程序原理是基于读取每个盘符下的Autorun.inf相关字段
Echo.
Echo [1] 仅仅删除所有盘符下的 Autorun 病毒
Echo [2] 删除所有盘符下的 Autorun 病毒并且建立同名免疫目录(推荐!)
Echo [3] 禁用系统的 Autorun 机制以避免 Autorun 病毒的再次感染
Echo [4] 取消所有盘符的 Autorun 病毒免疫
Echo [5] 删除并免疫指定盘符的 Autorun 病毒
Echo [6] 取消免疫指定盘符
Echo [7] 恢复相关注册表项默认值
Echo [0] 退出
Echo.
Set clearslt=
Set /p clearslt= 请输入您的选择(1/2/3/4/5/6/7/0):
If "%clearslt%"=="1" Goto clearauto1
If "%clearslt%"=="2" Goto clearauto2
If "%clearslt%"=="3" Goto clearauto3
If "%clearslt%"=="4" Goto clearauto4
If "%clearslt%"=="5" Goto clearauto5
If "%clearslt%"=="6" Goto clearauto6
If "%clearslt%"=="7" Goto clearauto7
If "%clearslt%"=="0" Exit
Goto clearauto
:clearauto1
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" >nul 2>nul
Del /a /f /q %%a:\autorun.inf >nul 2>nul
) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" >nul 2>nul
Del /a /f /q %%a:\autorun.inf >nul 2>nul
) >nul 2>nul
)
cls
Echo Autorun 病毒清除完毕，任意键返回……
pause>nul
Goto clearauto
:clearauto2
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目录不要删除!...\" & attrib +s +h +r "%%a:\%%b" & Echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %%a:\autorun.inf & Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目录不要删除!...\" & attrib +s +h +r "%%a:\%%b" & Echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %%a:\autorun.inf & Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
) >nul 2>nul
)
cls
Echo Autorun 病毒清除并免疫完毕，任意键返回……
pause>nul
Goto clearauto
:clearauto3
cls
Echo.
Echo 正在停止相关服务……
Echo.
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
net stop ShellHWDetection >nul 2>nul
sc config ShellHWDetection start= disabled >nul 2>nul
Rem 添加防止从回收站或仿回收站的目录中直接运行可执行文件的策略
Set REGPATH=HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths
Set SFLAG=/v SaferFlags /t REG_DWORD /d 0x00000000 /f
Set IDATA=/f /v ItemData /d "?:\Recyc?
reg add %REGPATH%\{00ffa5bf-abe7-4901-aacf-4f58aa31217a} %SFLAG%>nul
reg add %REGPATH%\{00ffa5bf-abe7-4901-aacf-4f58aa31217a} %IDATA%\*\*\*\*.*">nul
reg add %REGPATH%\{41fe7eed-c47a-46f6-840a-240796fd03cf} %SFLAG%>nul
reg add %REGPATH%\{41fe7eed-c47a-46f6-840a-240796fd03cf} %IDATA%\*\*\*.*">nul
reg add %REGPATH%\{4e93c91c-a40e-462e-9b89-3b0832d222d9} %SFLAG%>nul
reg add %REGPATH%\{4e93c91c-a40e-462e-9b89-3b0832d222d9} %IDATA%\*.*">nul
reg add %REGPATH%\{5bfc100b-d3fb-450e-88ec-6819ab56a9ff} %SFLAG%>nul
reg add %REGPATH%\{5bfc100b-d3fb-450e-88ec-6819ab56a9ff} %IDATA%\*\*\*\*.*">nul
reg add %REGPATH%\{5c5e2bcd-7057-43f4-830c-e4361d2afadd} %SFLAG%>nul
reg add %REGPATH%\{5c5e2bcd-7057-43f4-830c-e4361d2afadd} %IDATA%\*.*">nul
reg add %REGPATH%\{5f8ff865-0638-4c6e-98de-923e7bc6b330} %SFLAG%>nul
reg add %REGPATH%\{5f8ff865-0638-4c6e-98de-923e7bc6b330} %IDATA%\*\*\*.*">nul
reg add %REGPATH%\{649c1429-0e79-453c-abe9-b5682e035ae7} %SFLAG%>nul
reg add %REGPATH%\{649c1429-0e79-453c-abe9-b5682e035ae7} %IDATA%\*\*.*">nul
reg add %REGPATH%\{718f54b2-c669-4d7b-aeff-18d69f100034} %SFLAG%>nul
reg add %REGPATH%\{718f54b2-c669-4d7b-aeff-18d69f100034} %IDATA%\*\*.*">nul
reg add %REGPATH%\{8385d9d2-80c9-4ac1-a100-ed3e62863d97} %SFLAG%>nul
reg add %REGPATH%\{8385d9d2-80c9-4ac1-a100-ed3e62863d97} %IDATA%\*.*">nul
reg add %REGPATH%\{af2a4fcf-441c-421e-9663-52cd3502cfd7} %SFLAG%>nul
reg add %REGPATH%\{af2a4fcf-441c-421e-9663-52cd3502cfd7} %IDATA%\*\*\*.*">nul
reg add %REGPATH%\{b997f4b2-c037-4e97-b051-31f5d86df802} %SFLAG%>nul
reg add %REGPATH%\{b997f4b2-c037-4e97-b051-31f5d86df802} %IDATA%\*\*.*">nul
reg add %REGPATH%\{d4e7b6ff-d76f-407f-b8bb-ea0835f5babc} %SFLAG%>nul
reg add %REGPATH%\{d4e7b6ff-d76f-407f-b8bb-ea0835f5babc} /f /v ItemData /d "RECYC*.*">nul
Rem 清除喜欢利用回收站的移动磁盘自动运行病毒
For %%a In (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) Do (
For %%b In (exe pif com) Do (
Echo Y|cacls "%%a:\Recycler\*.%%b" /C /T /P everyone:F>nul 2>nul&Echo Y|cacls "%%a:\Recycled\*.%%b" /C /T /P everyone:F>nul 2>nul&Echo Y|cacls "%%a:\Recycled\Recycled\*.%%b" /C /T /P everyone:F>nul 2>nul
Del /A /F /S /Q "%%a:\Recycler\*.%%b">nul 2>nul&Del /A /F /S /Q "%%a:\Recycled\*.%%b">nul 2>nul&Del /A /F /S /Q "%%a:\Recycled\Recycled\*.%%b">nul 2>nul
)
)>nul 2>nul
Echo.
Echo 相关服务已停止并禁用，任意键返回……
pause >nul
Goto clearauto
:clearauto4
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%%a:\autorun.inf" & rd /s /q "%%a:\autorun.inf">nul 2>nul
)>nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%%a:\autorun.inf" & rd /s /q "%%a:\autorun.inf">nul 2>nul
)>nul 2>nul
)
cls
Echo.
Echo 已经解除全部盘符的免疫，任意键返回……
pause>nul
Goto clearauto
:clearauto5
cls
Echo.
Set pf=
Set /p pf= 请输入盘符，如"F:"(不包括引号)
Echo 即将免疫%pf%盘……|find /i ":"||Set pf=%pf%:&&Echo 即将免疫%pf%盘……
fsutil fsinfo drivetype %pf% |find /i "固定驱动器" && (
For /f "tokens=2 delims==" %%a In (%pf%\autorun.inf) Do Del /a /f /q "%pf%\%%a" & md "%pf%\%%a\免疫目录不要删除!...\" & attrib +s +h +r "%pf%\%%a" & Echo Y|cacls "%pf%\%%a" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %pf%\autorun.inf & md "%pf%\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %pf%\autorun.inf & Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:N >nul 2>nul
Goto DoneclearAuto
) >nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "可移动驱动器" && (
For /f "tokens=2 delims==" %%a In (%pf%\autorun.inf) Do Del /a /f /q "%pf%\%%a" & md "%pf%\%%a\免疫目录不要删除!...\" & attrib +s +h +r "%pf%\%%a" & Echo Y|cacls "%pf%\%%a" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %pf%\autorun.inf & md "%pf%\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %pf%\autorun.inf & Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:N >nul 2>nul
Goto DoneclearAuto
) >nul 2>nul
Echo.
Goto clearauto5
:DoneclearAuto
cls
Echo.
Echo 指定的磁盘 %pf% 已经成功进行了 Autorun 病毒的清除及免疫
Echo.
Echo [1] 继续免疫其他磁盘
Echo [0] 返回主菜单
Set choice=
Set /p choice= 请输入您的选择(1/0):
If "%choice%"=="1" Goto clearauto5
If "%choice%"=="0" Goto clearauto
Goto DoneclearAuto
:clearauto6
cls
Echo.
Set pf=
Set /p pf= 请输入盘符，如"F:"(不包括引号)
Echo 即将取消免疫%pf%盘……|find /i ":"||Set pf=%pf%:&&Echo 即将取消免疫%pf%盘……
fsutil fsinfo drivetype %pf% |find /i "固定驱动器" && (
Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%pf%\autorun.inf" & rd /s /q "%pf%\autorun.inf">nul 2>nul
Goto DoneUnauto
)>nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "可移动驱动器" && (
Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%pf%\autorun.inf" & rd /s /q "%pf%\autorun.inf">nul 2>nul
Goto DoneUnauto
)>nul 2>nul
Echo.
Goto clearauto6
:DoneUnauto
cls
Echo.
Echo 指定的磁盘 %pf% 已经成功解除了 Autorun 病毒免疫
Echo.
Echo [1] 继续解除免疫其他磁盘
Echo [0] 返回主菜单
Set choice=
Set /p choice= 请输入您的选择(1/0):
If "%choice%"=="1" Goto clearauto6
If "%choice%"=="0" Goto clearauto
Goto DoneUnauto
:clearauto7
cls
Rem 防止在资源管理器中彻底隐藏文件、禁止文件等
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /v CheckedValue /t REG_DWORD /d 0x00000001 /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\DisallowRun" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v DisallowRun /f>nul 2>nul
Rem 防止转移启动组位置
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Startup /d "%USERPROFILE%\「开始」菜单\程序\启动" /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Startup" /d "%ALLUSERSPROFILE%\「开始」菜单\程序\启动" /f>nul 2>nul
Echo.
Echo 相关注册表恢复完毕，任意键返回……
pause>nul
Goto clearauto
热心网友
时间：2024-02-19 22:03
最近U盘病毒非常猖獗，经过分析这种病毒的传播主要借助与Autorun.inf文件，病毒先将自身复制到U盘，然后再创建一个Autorun.inf文件。当你在你双击U盘时，会根据Autorun.inf中的设置去运行U盘中的病毒，然后将其复制到硬盘的各个盘符下无法删除。重装或一键恢复了XP系统，双击其他分区，比如D盘，都打不开，只能用右键打开。这就是中了Autorun.INF类病毒的表现。今天我们就把干掉Autorun.inf类病毒的方法和预防的手段跟大家分享一下。
手工轻松干掉Autorun.inf
中了这类病毒后，各个分区的根目录下都会生成一个隐藏属性的Autorun.inf文件，双击打开“我的电脑”，点击“工具”，再点击“查看”，去掉“隐藏受保护的操作系统文件”及选中“显示所有文件和文件夹”，再点“确定”把所有的隐藏属性打开（见图1）。右键打开任一分区，如D盘，就可以看见Autorun.inf这个文件，再右键打开Autorun.inf会看到open=xxx.exe（xxx就是病毒的名称），如果病毒没进程程保护的话，删掉各个分区的Autorun.inf和xxx.exe就可以把病毒删除了，删除病毒后，还要把病毒的磁盘关联改回来。
运行regedit.exe来到[HKEY_CLASSES_ROOT\Drive\shell]下，把“默认”改成none（见图2），再到"HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer下删掉ountPoints2这一项（如果有这一项的话），到此，就能双击打开任意盘符了。
为了方便大家清除Autorun.inf类病毒，我们为大家用RAR做了一个自压解清除Autorun.inf和修复磁盘及EXE文件关联的小工具，这个小工具由delinfvir.cmd、del.cmd、del.reg、drivefix.reg、undel.reg、attrib.exe、taskkill.exe等文件组成，解压后马上运行drivefix.cmd这个批处理，之后会重启系统，启动到“欢迎使用”在加载explore.exe前进行清除Autorun.inf等相关病毒的操作，需耐心等候片刻。
小提示：因为工具本身要在注册表“runonce”处添加一个自启项，在重启时运行del.cmd清除病毒，清除完后会自行删除该自启项的，请放心。如果装有杀毒软件，比如KV，运行这个工具时会提示工具会在“runonce”处添加启动项，请点“允许”，否则重启后清除不了Autorun.inf类病毒。
摆脱Autorun.inf的纠缠
如果你的电脑已经中毒，并且重装或一键恢复了XP系统，双击其他分区，比如D盘，都打不开，这时也不必担心，我们来告诉你如何清除：首先要下载费尔木马强力清除助手,它可以抑制病毒的在生。方法如下：
第一步：打开费尔木马强力清除助手。
第二步：在文件名后面输入“D:\Autorun.inf”（不包括“”），在把抑制文件再次生成选上（见图3），点击清除即可。其它盘符同理，C盘除外。
第三步：重新做下系统便可恢复正常，如果有GHOST的朋友直接恢复就OK了。
第四步：重做系统后可能每个盘符下都会有残留，只要将电脑现设置成显示所有文件就可看到。将其手动删除就可以了。
防患未然避免Autorun
如何避免中Autorun.inf的招呢？这里教给大家一个好办法，100%好用。只要可以阻止Autorun.inf文件的创建，那么这种病毒就无法在U盘上传播了。只要在U盘的根目下建立一个文件夹，名字就叫Autorun.inf，因为在同一目录下，同名的文件和文件夹是不能共存的。这样病毒就无法再创建Autorun.inf文件了。移动硬盘也是如此，只要在每个分区上创建一个Autorun.inf文件夹就OK了。
热心网友
时间：2024-02-19 22:04
我解决过的~
很方便的。
其实，这些文件夹.exe文件，只是病毒文件，图标做成了文件夹形式而已。
先用资源管理器打开U盘；
然后，工具-文件夹选项-查看-显示所有文件和文件夹-应用-确定；
然后，你会发现以前的文件就又出现了，但是，只是被隐藏了而已；
随后，选中那些.exe结尾的文件夹图标的文件，Shift+Del，彻底删除；
最后，选中被隐藏了的文件夹，取消隐藏即可。
当然，最后的最后，最好还是再全盘杀毒一下~不怕一万，就怕万一~以防万一嘛~
热心网友
时间：2024-02-19 22:04
Autorun.inf是一种病毒主要特征,有Autorun.inf的病毒文件只要一点击就会启动病毒传播,可能是Autorun.inf感染到其他的文件或者有着千丝万缕牵连,卡巴才会连带删掉,如他们所说的去恢复就行了
谢谢采纳,谢谢采纳!
热心网友
时间：2024-02-19 22:05
如果Autorun.inf文件夹里没有Autorun.inf这个文件就说明没有病毒，Autorun.inf文件是病毒Autorun.inf文件夹是防Autorun.inf这个病毒的文件夹
热心网友
时间：2024-02-19 22:06
关于autorun.inf
的问题
Autorun.inf
有两种可能
1.中了AUTO病毒
使用这些工具查杀：
http://www.17ai.org.cn/safe/upan.htm
http://www.17ai.org.cn/qt/auto.htm
2.你曾经使用某些工具对磁盘进行免疫
这个就是免疫文件夹
可以使用任一U盘病毒专杀工具解除免疫：
http://www.17ai.org.cn/safe/upan.htm
